歡迎光臨
每天分享高質量文章

計算機實驗室之樹莓派:課程 10 輸入01 | Linux 中國

這是第一堂輸入課,會教授一些關於驅動和鏈接的理論,同樣也包含鍵盤的知識,最後以在屏幕上顯示文本結束。

— Alex Chadwick

 

歡迎進入輸入課程系列。在本系列,你將會學會如何使用鍵盤接收輸入給樹莓派。我們將會從揭示輸入開始本課,然後轉向更傳統的文本提示符。

這是第一堂輸入課,會教授一些關於驅動和鏈接的理論,同樣也包含鍵盤的知識,最後以在屏幕上顯示文本結束。

1、開始

希望你已經完成了 OK 系列課程,這會對你完成屏幕系列課程很有幫助。很多 OK 課程上的檔案會被使用而不會做解釋。如果你沒有這些檔案,或者希望使用一個正確的實現,可以從該堂課的下載頁[1]下載模板。如果你使用你自己的實現,請刪除呼叫了 SetGraphicsAddress 之後全部的代碼。

2、USB

如你所知,樹莓派 B 型有兩個 USB 接口,通常用來連接一個滑鼠和一個鍵盤。這是一個非常好的設計決策,USB 是一個非常通用的接口,很多種設備都可以使用它。這就很容易為它設計新外設,很容易為它編寫設備驅動,而且通過 USB 集線器可以非常容易擴展。還能更好嗎?當然是不能,實際上對一個操作系統開發者來說,這就是我們的噩夢。USB 標準太大了。我是說真的,在你思考如何連接設備之前,它的文件將近 700 頁。

USB 標準的設計目的是通過複雜的軟體來簡化硬體交互。

我和很多愛好操作系統的開發者談過這些,而他們全部都說幾句話:不要抱怨。“實現這個需要花費很久時間”,“你不可能寫出關於 USB 的教程”,“收益太小了”。在很多方面,他們是對的,我不可能寫出一個關於 USB 標準的教程,那得花費幾周時間。我同樣不能教授如何為全部所有的設備編寫外設驅動,所以使用自己寫的驅動是沒什麼用的。然而,即便不能做到最好,我仍然可以獲取一個正常工作的 USB 驅動,拿一個鍵盤驅動,然後教授如何在操作系統中使用它們。我開始尋找可以運行在一個甚至不知道檔案是什麼的操作系統的自由驅動,但是我一個都找不到,它們都太高層了,所以我嘗試寫一個。大家說的都對,這耗費了我幾周時間。然而我可以高興的說我做的這些工作沒有獲取操作系統以外的幫助,並且可以和滑鼠和鍵盤通信。這絕不是完整的、高效的,或者正確的,但是它能工作。驅動是以 C 編寫的,而且有興趣的可以在下載頁找到全部原始碼。

所以,這一個教程不會是 USB 標準的課程(一點也沒有)。實際上我們將會看到如何使用其他人的代碼。

3、鏈接

既然我們要引進外部代碼到操作系統,我們就需要談一談鏈接linking。鏈接是一種過程,可以在程式或者操作系統中鏈接函式。這意味著當一個程式生成之後,我們不必要編寫每一個函式(幾乎可以肯定,實際上並非如此)。鏈接就是我們做的用來把我們程式和別人代碼中的函式連結在一起。這個實際上已經在我們的操作系統進行了,因為聯結器把所有不同的檔案鏈接在一起,每個都是分開編譯的。

鏈接允許我們製作可重用的代碼庫,所有人都可以在他們的程式中使用。

有兩種鏈接方式:靜態和動態。靜態鏈接就像我們在製作自己的操作系統時進行的。聯結器找到全部函式的地址,然後在鏈接結束前,將這些地址都寫入代碼中。動態鏈接是在程式“完成”之後。當程式加載後,動態聯結器檢查程式,然後在操作系統的庫找到所有不在程式里的函式。這就是我們的操作系統最終應該能夠完成的一項工作,但是現在所有東西都將是靜態鏈接的。

程式經常呼叫呼叫庫,這些庫會呼叫其它的庫,直到最終呼叫了我們寫的操作系統的庫。

我編寫的 USB 驅動程式適合靜態編譯。這意味著我給你的是每個檔案的編譯後的代碼,然後聯結器找到你的代碼中的那些沒有實現的函式,就將這些函式鏈接到我的代碼。在本課的 下載頁[1]是一個 makefile 和我的 USB 驅動,這是接下來需要的。下載並使用這個 makefile 替換你的代碼中的 makefile, 同事將驅動放在和這個 makefile 相同的檔案夾。

4、鍵盤

為了將輸入傳給我們的操作系統,我們需要在某種程度上理解鍵盤是如何實際工作的。鍵盤有兩種按鍵:普通鍵和修飾鍵。普通按鍵是字母、數字、功能鍵,等等。它們構成了鍵盤上幾乎全部按鍵。修飾鍵是多達 8 個的特殊鍵。它們是左 shift、右 shift、左 ctrl、右 ctrl、左 alt、右 alt、左 GUI 和右 GUI。鍵盤可以檢測出所有的組合中那個修飾鍵被按下了,以及最多 6 個普通鍵。每次一個按鈕變化了(例如,是按下了還是釋放了),鍵盤就會報告給電腦。通常,鍵盤也會有 3 個 LED 燈,分別指示大寫鎖定,數字鍵鎖定,和滾動鎖定,這些都是由電腦控制的,而不是鍵盤自己。鍵盤也可能有更多的燈,比如電源、靜音,等等。

對於標準 USB 鍵盤,有一個按鍵值的表,每個鍵盤按鍵都一個唯一的數字,每個可能的 LED 也類似。下麵的表格列出了前 126 個值。

表 4.1 USB 鍵盤值

< 如顯示不全,請左右滑動 >
序號 描述 序號 描述 序號 描述 序號 描述
4 a 和 A 5 b 和 B 6 c 和 C 7 d 和 D
8 e 和 E 9 f 和 F 10 g 和 G 11 h 和 H
12 i 和 I 13 j 和 J 14 k 和 K 15 l 和 L
16 m 和 M 17 n 和 N 18 o 和 O 19 p 和 P
20 q 和 Q 21 r 和 R 22 s 和 S 23 t 和 T
24 u 和 U 25 v 和 V 26 w 和 W 27 x 和 X
28 y 和 Y 29 z 和 Z 30 1 和 ! 31 2 和 @
32 3 和 # 33 4 和 $ 34 5 和 % 35 6 和 ^
36 7 和 & 37 8 和 * 38 9 和 ( 39 0 和 )
40 ReturnEnter 41 Escape 42 DeleteBackspace 43 Tab
44 Spacebar 45 - 和 _ 46 = 和 + 47 [ 和 {
48 ] 和 } 49 \ 和 | 50 # 和 ~ 51 ; 和 :
52 ' 和 " 53 ` 和 ~ 54 , 和 < 55 . 和 >
56 / 和 ? 57 Caps Lock 58 F1 59 F2
60 F3 61 F4 62 F5 63 F6
64 F7 65 F8 66 F9 67 F10
68 F11 69 F12 70 Print Screen 71 Scroll Lock
72 Pause 73 Insert 74 Home 75 Page Up
76 Delete forward 77 End 78 Page Down 79 Right Arrow
80 Left Arrow 81 Down Arrow 82 Up Arrow 83 Num Lock
84 小鍵盤 / 85 小鍵盤 * 86 小鍵盤 - 87 小鍵盤 +
88 小鍵盤 Enter 89 小鍵盤 1 和 End 90 小鍵盤 2 和 Down Arrow 91 小鍵盤 3 和 Page Down
92 小鍵盤 4 和 Left Arrow 93 小鍵盤 5 94 小鍵盤 6 和 Right Arrow 95 小鍵盤 7 和 Home
96 小鍵盤 8 和 Up Arrow 97 小鍵盤 9 和 Page Up 98 小鍵盤 0 和 Insert 99 小鍵盤 . 和 Delete
100 \ 和 | 101 Application 102 Power 103 小鍵盤 =
104 F13 105 F14 106 F15 107 F16
108 F17 109 F18 110 F19 111 F20
112 F21 113 F22 114 F23 115 F24
116 Execute 117 Help 118 Menu 119 Select
120 Stop 121 Again 122 Undo 123 Cut
124 Copy 125 Paste 126 Find 127 Mute
128 Volume Up 129 Volume Down

完全串列可以在HID 頁表 1.12[2]的 53 頁,第 10 節找到。

5、車輪後的螺母

通常,當你使用其他人的代碼,他們會提供一份自己代碼的總結,描述代碼都做了什麼,粗略介紹了是如何工作的,以及什麼情況下會出錯。下麵是一個使用我的 USB 驅動的相關步驟要求。

這些總結和代碼的描述組成了一個 API – 應用程式產品接口。

表 5.1 CSUD 中和鍵盤相關的函式

< 如顯示不全,請左右滑動 >
函式 引數 傳回值 描述
UsbInitialise r0 是結果碼 這個方法是一個集多種功能於一身的方法,它加載 USB 驅動程式,列舉所有設備並嘗試與它們通信。這種方法通常需要大約一秒鐘的時間來執行,但是如果插入幾個 USB 集線器,執行時間會明顯更長。在此方法完成之後,鍵盤驅動程式中的方法就可用了,不管是否確實插入了鍵盤。傳回代碼如下解釋。
UsbCheckForChange 本質上提供與 UsbInitialise相同的效果,但不提供相同的一次初始化。該方法遞迴地檢查每個連接的集線器上的每個端口,如果已經添加了新設備,則添加它們。如果沒有更改,這應該是非常快的,但是如果連接了多個設備的集線器,則可能需要幾秒鐘的時間。
KeyboardCount r0 是計數 傳回當前連接並檢測到的鍵盤數量。UsbCheckForChange 可能會對此進行更新。預設情況下最多支持 4 個鍵盤。可以通過這個驅動程式訪問多達這麼多的鍵盤。
KeyboardGetAddress r0 是索引 r0 是地址 檢索給定鍵盤的地址。所有其他函式都需要一個鍵盤地址,以便知道要訪問哪個鍵盤。因此,要與鍵盤通信,首先要檢查計數,然後檢索地址,然後使用其他方法。註意,在呼叫 UsbCheckForChange 之後,此方法傳回的鍵盤順序可能會改變。
KeyboardPoll r0 是地址 r0 是結果碼 從鍵盤讀取當前鍵狀態。這是通過直接輪詢設備來操作的,與最佳實踐相反。這意味著,如果沒有頻繁地呼叫此方法,可能會錯過一個按鍵。所有讀取方法只傳回上次輪詢時的值。
KeyboardGetModifiers r0 是地址 r0 是修飾鍵狀態 檢索上次輪詢時修飾鍵的狀態。這是兩邊的 shift 鍵、alt 鍵和 GUI 鍵。這回作為一個位欄位傳回,這樣,位 0 中的 1 表示左控制元件被保留,位 1 表示左 shift,位 2 表示左 alt ,位 3 表示左 GUI,位 4 到 7 表示前面幾個鍵的右版本。如果有問題,r0 包含 0。
KeyboardGetKeyDownCount r0 是地址 r0 是計數 檢索當前按下鍵盤的鍵數。這排除了修飾鍵。這通常不能超過 6。如果有錯誤,這個方法傳回 0。
KeyboardGetKeyDown r0 是地址,
r1 鍵號
r0 是掃描碼 檢索特定按下鍵的掃描碼(見表 4.1)。通常,要計算出哪些鍵是按下的,可以呼叫 KeyboardGetKeyDownCount,然後多次呼叫 KeyboardGetKeyDown ,將 r1 的值遞增,以確定哪些鍵是按下的。如果有問題,傳回 0。可以(但不建議這樣做)在不呼叫 KeyboardGetKeyDownCount的情況下呼叫此方法將 0 解釋為沒有按下的鍵。註意,順序或掃描代碼可以隨機更改(有些鍵盤按數字排序,有些鍵盤按時間排序,沒有任何保證)。
KeyboardGetKeyIsDown r0 是地址,
r1 掃描碼
r0 是狀態 除了 KeyboardGetKeyDown 之外,還可以檢查按下的鍵中是否有特定的掃描碼。如果沒有,傳回 0;如果有,傳回一個非零值。當檢測特定的掃描碼(例如尋找 ctrl+c)時更快。出錯時,傳回 0。
KeyboardGetLedSupport r0 是地址 r0 是 LED 檢查特定鍵盤支持哪些 LED。第 0 位代表數字鎖定,第 1 位代表大寫鎖定,第 2 位代表滾動鎖定,第 3 位代表合成,第 4 位代表假名,第 5 位代表電源,第 6 位代表 Shift ,第 7 位代表靜音。根據 USB 標準,這些 LED 都不是自動更新的(例如,當檢測到大寫鎖定掃描代碼時,必須手動設置大寫鎖定 LED)。
KeyboardSetLeds r0 是地址,
r1 是 LED
r0 是結果碼 試圖打開/關閉鍵盤上指定的 LED 燈。查看下麵的結果代碼值。參見 KeyboardGetLedSupport 獲取 LED 的值。

有幾種方法傳回“傳回值”。這些都是 C 代碼的老生常談了,就是用數字代表函式呼叫發生了什麼。通常情況, 0 總是代表操作成功。下麵的是驅動用到的傳回值。

傳回值是一種處理錯誤的簡單方法,但是通常更優雅的解決途徑會出現於更高層次的代碼。

表 5.2 – CSUD 傳回值

< 如顯示不全,請左右滑動 >
代碼 描述
0 方法成功完成。
-2 引數:函式呼叫了無效引數。
-4 設備:設備沒有正確響應請求。
-5 不匹配:驅動不適用於這個請求或者設備。
-6 編譯器:驅動沒有正確編譯,或者被破壞了。
-7 記憶體:驅動用盡了記憶體。
-8 超時:設備沒有在預期的時間內響應請求。
-9 斷開連接:被請求的設備斷開連接,或者不能使用。

驅動的通常用法如下:

1. 呼叫 UsbInitialise
2. 呼叫 UsbCheckForChange
3. 呼叫 KeyboardCount
4. 如果傳回 0,重覆步驟 2。
5. 針對你支持的每個鍵盤:

1. 呼叫 KeyboardGetAddress
2. 呼叫 KeybordGetKeyDownCount
3. 針對每個按下的按鍵:

1. 檢查它是否已經被按下了
2. 儲存按下的按鍵
4. 針對每個儲存的按鍵:

1. 檢查按鍵是否被釋放了
2. 如果釋放了就刪除
6. 根據按下/釋放的案件執行操作
7. 重覆步驟 2

最後,你可以對鍵盤做所有你想做的任何事了,而這些方法應該允許你訪問鍵盤的全部功能。在接下來的兩節課,我們將會著眼於完成文本終端的輸入部分,類似於大部分的命令列電腦,以及命令的解釋。為了做這些,我們將需要在更有用的形式下得到一個鍵盤輸入。你可能註意到我的驅動是(故意的)沒有太大幫助,因為它並沒有方法來判斷是否一個按鍵剛剛按下或釋放了,它只有方法來判斷當前那個按鍵是按下的。這就意味著我們需要自己編寫這些方法。

6、可用更新

首先,讓我們實現一個 KeyboardUpdate 方法,檢查第一個鍵盤,並使用輪詢方法來獲取當前的輸入,以及儲存最後一個輸入來對比。然後我們可以使用這個資料和其它方法來將掃描碼轉換成按鍵。這個方法應該按照下麵的說明準確操作:

重覆檢查更新被稱為“輪詢”。這是針對驅動 IO 中斷而言的,這種情況下設備在準備好後會發一個信號。

1. 提取一個儲存好的鍵盤地址(初始值為 0)。
2. 如果不是 0 ,進入步驟 9.
3. 呼叫 UsbCheckForChange 檢測新鍵盤。
4. 呼叫 KeyboardCount 檢測有幾個鍵盤在線。
5. 如果傳回 0,意味著沒有鍵盤可以讓我們操作,只能退出了。
6. 呼叫 KeyboardGetAddress 引數是 0,獲取第一個鍵盤的地址。
7. 儲存這個地址。
8. 如果這個值是 0,那麼退出,這裡應該有些問題。
9. 呼叫 KeyboardGetKeyDown 6 次,獲取每次按鍵按下的值並儲存。
10. 呼叫 KeyboardPoll
11. 如果傳回值非 0,進入步驟 3。這裡應該有些問題(比如鍵盤斷開連接)。

要儲存上面提到的值,我們將需要下麵 .data 段的值。

  1. .section .data
  2. .align 2
  3. KeyboardAddress:
  4. .int 0
  5. KeyboardOldDown:
  6. .rept 6
  7. .hword 0
  8. .endr
  1. .hword num 直接將半字的常數插入檔案。
  1. .rept num [commands] .endr 複製 `commands` 命令到輸出 num 次。

試著自己實現這個方法。對此,我的實現如下:

1、我們加載鍵盤的地址。

  1. .section .text
  2. .globl KeyboardUpdate
  3. KeyboardUpdate:
  4. push {r4,r5,lr}
  5. kbd .req r4
  6. ldr r0,=KeyboardAddress
  7. ldr kbd,[r0]

2、如果地址非 0,就說明我們有一個鍵盤。呼叫 UsbCheckForChanges 慢,所以如果一切正常,我們要避免呼叫這個函式。

  1. teq kbd,#0
  2. bne haveKeyboard$

3、如果我們一個鍵盤都沒有,我們就必須檢查新設備。

  1. getKeyboard$:
  2. bl UsbCheckForChange

4、如果有新鍵盤添加,我們就會看到這個。

  1. bl KeyboardCount

5、如果沒有鍵盤,我們就沒有鍵盤地址。

  1. teq r0,#0
  2. ldreq r1,=KeyboardAddress
  3. streq r0,[r1]
  4. beq return$

6、讓我們獲取第一個鍵盤的地址。你可能想要支持更多鍵盤。

  1. mov r0,#0
  2. bl KeyboardGetAddress

7、儲存鍵盤地址。

  1. ldr r1,=KeyboardAddress
  2. str r0,[r1]

8、如果我們沒有鍵盤地址,這裡就沒有其它活要做了。

  1. teq r0,#0
  2. beq return$
  3. mov kbd,r0

9、迴圈查詢全部按鍵,在 KeyboardOldDown 儲存下來。如果我們詢問的太多了,傳回 0 也是正確的。

  1. saveKeys$:
  2. mov r0,kbd
  3. mov r1,r5
  4. bl KeyboardGetKeyDown
  5. ldr r1,=KeyboardOldDown
  6. add r1,r5,lsl #1
  7. strh r0,[r1]
  8. add r5,#1
  9. cmp r5,#6
  10. blt saveKeys$

10、現在我們得到了新的按鍵。

  1. mov r0,kbd
  2. bl KeyboardPoll

11、最後我們要檢查 KeyboardOldDown 是否工作了。如果沒工作,那麼我們可能是斷開連接了。

  1. teq r0,#0
  2. bne getKeyboard$
  3. return$:
  4. pop {r4,r5,pc}
  5. .unreq kbd

有了我們新的 KeyboardUpdate 方法,檢查輸入變得簡單,固定周期呼叫這個方法就行,而它甚至可以檢查鍵盤是否斷開連接,等等。這是一個有用的方法,因為我們實際的按鍵處理會根據條件不同而有所差別,所以能夠用一個函式調以它的原始方式獲取當前的輸入是可行的。下一個方法我們希望它是 KeyboardGetChar,簡單的傳回下一個按下的按鈕的 ASCII 字符,或者如果沒有按鍵按下就傳回 0。這可以擴展到支持如果它按下一個特定時間當做多次按下按鍵,也支持鎖定鍵和修飾鍵。

如果我們有一個 KeyWasDown 方法可以使這個方法有用起來,如果給定的掃描代碼不在 KeyboardOldDown 值中,它只傳回 0,否則傳回一個非零值。你可以自己嘗試一下。與往常一樣,可以在下載頁面找到解決方案。

7、查找表

KeyboardGetChar 方法如果寫得不好,可能會非常複雜。有 100 多種掃描碼,每種代碼都有不同的效果,這取決於 shift 鍵或其他修飾符的存在與否。並不是所有的鍵都可以轉換成一個字符。對於一些字符,多個鍵可以生成相同的字符。在有如此多可能性的情況下,一個有用的技巧是查找表。查找表與物理意義上的查找表非常相似,它是一個值及其結果的表。對於一些有限的函式,推匯出答案的最簡單方法就是預先計算每個答案,然後通過檢索傳回正確的答案。在這種情況下,我們可以在記憶體中建立一個序列的值,序列中第 n 個值就是掃描代碼 n 的 ASCII 字符代碼。這意味著如果一個鍵被按下,我們的方法只需要檢測到,然後從表中檢索它的值。此外,我們可以為當按住 shift 鍵時的值單獨創建一個表,這樣按下 shift 鍵就可以簡單地換個我們用的表。

在編程的許多領域,程式越大,速度越快。查找表很大,但是速度很快。有些問題可以通過查找表和普通函式的組合來解決。

在 .section .data 命令之後,複製下麵的表:

  1. .align 3
  2. KeysNormal:
  3. .byte 0x0, 0x0, 0x0, 0x0, 'a', 'b', 'c', 'd'
  4. .byte 'e', 'f', 'g', 'h', 'i', 'j', 'k', 'l'
  5. .byte 'm', 'n', 'o', 'p', 'q', 'r', 's', 't'
  6. .byte 'u', 'v', 'w', 'x', 'y', 'z', '1', '2'
  7. .byte '3', '4', '5', '6', '7', '8', '9', '0'
  8. .byte '\n', 0x0, '\b', '\t', ' ', '-', '=', '['
  9. .byte ']', '\\\', '#', ';', '\'', '`', ',', '.'
  10. .byte '/', 0x0, 0x0, 0x0, 0x0, 0x0, 0x0, 0x0
  11. .byte 0x0, 0x0, 0x0, 0x0, 0x0, 0x0, 0x0, 0x0
  12. .byte 0x0, 0x0, 0x0, 0x0, 0x0, 0x0, 0x0, 0x0
  13. .byte 0x0, 0x0, 0x0, 0x0, '/', '*', '-', '+'
  14. .byte '\n', '1', '2', '3', '4', '5', '6', '7'
  15. .byte '8', '9', '0', '.', '\\\', 0x0, 0x0, '='
  16. .align 3
  17. KeysShift:
  18. .byte 0x0, 0x0, 0x0, 0x0, 'A', 'B', 'C', 'D'
  19. .byte 'E', 'F', 'G', 'H', 'I', 'J', 'K', 'L'
  20. .byte 'M', 'N', 'O', 'P', 'Q', 'R', 'S', 'T'
  21. .byte 'U', 'V', 'W', 'X', 'Y', 'Z', '!', '"'
  22. .byte '£', '$', '%', '^', '&', '*', '(', ')'
  23. .byte '\n', 0x0, '\b', '\t', ' ', '_', '+', '{'
  24. .byte '}', '|', '~', ':', '@', '¬', ''
  25. .byte '?', 0x0, 0x0, 0x0, 0x0, 0x0, 0x0, 0x0
  26. .byte 0x0, 0x0, 0x0, 0x0, 0x0, 0x0, 0x0, 0x0
  27. .byte 0x0, 0x0, 0x0, 0x0, 0x0, 0x0, 0x0, 0x0
  28. .byte 0x0, 0x0, 0x0, 0x0, '/', '*', '-', '+'
  29. .byte '\n', '1', '2', '3', '4', '5', '6', '7'
  30. .byte '8', '9', '0', '.', '|', 0x0, 0x0, '='

這些表直接將前 104 個掃描碼映射到 ASCII 字符作為一個位元組表。我們還有一個單獨的表來描述 shift 鍵對這些掃描碼的影響。我使用 ASCII null 字符(0)表示所有沒有直接映射的 ASCII 鍵(例如功能鍵)。退格映射到 ASCII 退格字符(8 表示 \b),enter 映射到 ASCII 新行字符(10 表示 \n), tab 映射到 ASCII 水平製表符(9 表示 \t)。

.byte num 直接插入位元組常量 num 到檔案。

.

大部分的彙編器和編譯器識別轉義序列;如 \t 這樣的字符序列會插入該特殊字符。

KeyboardGetChar 方法需要做以下工作:

1. 檢查 KeyboardAddress 是否傳回 0。如果是,則傳回 0。
2. 呼叫 KeyboardGetKeyDown 最多 6 次。每次:

1. 如果按鍵是 0,跳出迴圈。
2. 呼叫 KeyWasDown。 如果傳回是,處理下一個按鍵。
3. 如果掃描碼超過 103,進入下一個按鍵。
4. 呼叫 KeyboardGetModifiers
5. 如果 shift 是被按著的,就加載 KeysShift 的地址,否則加載 KeysNormal 的地址。
6. 從表中讀出 ASCII 碼值。
7. 如果是 0,進行下一個按鍵,否則傳回 ASCII 碼值並退出。
3. 傳回 0。

試著自己實現。我的實現展示在下麵:

1、簡單的檢查我們是否有鍵盤。

  1. .globl KeyboardGetChar
  2. KeyboardGetChar:
  3. ldr r0,=KeyboardAddress
  4. ldr r1,[r0]
  5. teq r1,#0
  6. moveq r0,#0
  7. moveq pc,lr

2、r5 將會儲存按鍵的索引,r4 儲存鍵盤的地址。

  1. push {r4,r5,r6,lr}
  2. kbd .req r4
  3. key .req r6
  4. mov r4,r1
  5. mov r5,#0
  6. keyLoop$:
  7. mov r0,kbd
  8. mov r1,r5
  9. bl KeyboardGetKeyDown

2.1、 如果掃描碼是 0,它要麼意味著有錯,要麼說明沒有更多按鍵了。

  1. teq r0,#0
  2. beq keyLoopBreak$

2.2、如果按鍵已經按下了,那麼他就沒意義了,我們只想知道按下的按鍵。

  1. mov key,r0
  2. bl KeyWasDown
  3. teq r0,#0
  4. bne keyLoopContinue$

2.3、如果一個按鍵有個超過 104 的掃描碼,它將會超出我們的表,所以它是無關的按鍵。

  1. cmp key,#104
  2. bge keyLoopContinue$

2.4、我們需要知道修飾鍵來推斷字符。

  1. mov r0,kbd
  2. bl KeyboardGetModifiers
2.5、. 當將字符更改為其 shift 變體時,我們要同時檢測左 shift 鍵和右 shift 鍵。記住,tst 指令計算的是邏輯和,然後將其與 0 進行比較,所以當且僅當移位位都為 0 時,它才等於 0。
  1. tst r0,#0b00100010
  2. ldreq r0,=KeysNormal
  3. ldrne r0,=KeysShift

2.6、現在我們可以從查找表加載按鍵了。

  1. ldrb r0,[r0,key]

2.7、如果查找碼包含一個 0,我們必須繼續。為了繼續,我們要增加索引,並檢查是否到 6 次了。

  1. teq r0,#0
  2. bne keyboardGetCharReturn$
  3. keyLoopContinue$:
  4. add r5,#1
  5. cmp r5,#6
  6. blt keyLoop$

3、在這裡我們傳回我們的按鍵,如果我們到達 keyLoopBreak$ ,然後我們就知道這裡沒有按鍵被握住,所以傳回 0。

  1. keyLoopBreak$:
  2. mov r0,#0
  3. keyboardGetCharReturn$:
  4. pop {r4,r5,r6,pc}
  5. .unreq kbd
  6. .unreq key

8、記事本操作系統

現在我們有了 KeyboardGetChar 方法,可以創建一個操作系統,只打印出用戶對著屏幕所寫的內容。為了簡單起見,我們將忽略所有非常規的鍵。在 main.s,刪除 bl SetGraphicsAddress 之後的所有代碼。呼叫 UsbInitialise,將 r4 和 r5 設置為 0,然後迴圈執行以下命令:

1. 呼叫 KeyboardUpdate
2. 呼叫 KeyboardGetChar
3. 如果傳回 0,跳轉到步驟 1
4. 複製 r4 和 r5 到 r1 和 r2 ,然後呼叫 DrawCharacter
5. 把 r0 加到 r4
6. 如果 r4 是 1024,將 r1 加到 r5,然後設置 r4 為 0。
7. 如果 r5 是 768,設置 r5 為0
8. 跳轉到步驟 1

現在編譯,然後在樹莓派上測試。你幾乎可以立即開始在屏幕上輸入文本。如果沒有工作,請參閱我們的故障排除頁面。

當它工作時,祝賀你,你已經實現了與計算機的接口。現在你應該開始意識到,你幾乎已經擁有了一個原始的操作系統。現在,你可以與計算機交互、發出命令,併在屏幕上接收反饋。在下一篇教程輸入02[3]中,我們將研究如何生成一個全文本終端,用戶在其中輸入命令,然後計算機執行這些命令。

 

赞(0)

分享創造快樂